Generating multiline axis labels in SAS PRO | SAS Code Fragments

You can read the Hospital Doctor Patient Dataset into SAS and run many linear and generalized linear mixed effects models in SAS using this code. The output is not included, but the syntax is. For more details on the dataset, you should see the original R page that simulates the data HDP Simulation.

/*SAS*/
/*read data in from internet*/
filename tmp url 'http://statistics.ats.ucla.edu/stat/data/hdp.csv';


data hdp;
infile tmp dlm=',' firstobs=2;
input tumorsize co2 pain wound mobility ntumors nmorphine 
  remission lungcapacity Age Married $ FamilyHx $ SmokingHx $
  Sex $ CancerStage $ LengthofStay WBC RBC BMI IL6 CRP DID $
  Experience School $ Lawsuits HID $ Medicaid;
run;

proc contents data=hdp;
run;

proc mixed noclprint;
  class FamilyHx CancerStage SmokingHx DID;
  model tumorsize = FamilyHx LengthofStay CancerStage SmokingHx|Age / solution;
  random intercept LengthofStay / subject=DID;
run;

proc mixed noclprint;
  class FamilyHx CancerStage SmokingHx DID;
  model co2 = FamilyHx LengthofStay CancerStage SmokingHx|Age / solution;
  random intercept LengthofStay / subject=DID;
run;

proc mixed noclprint;
  class Sex DID;
  model pain = Sex IL6 | CRP / solution;
  random intercept / subject=DID;
run;

proc mixed noclprint;
  class Married Sex DID HID;
  model wound = Married | Sex RBC Experience / solution;
  random intercept / subject=HID;
  random intercept RBC / subject=DID(HID);
run;

proc mixed noclprint;
  class School DID HID;
  model mobility = Age BMI Experience School Lawsuits Medicaid / solution;
  random intercept / subject=HID;
  random intercept / subject=DID(HID);
run;

/* code does not work */
proc glimmix noclprint chol method=laplace;
  class FamilyHx CancerStage DID HID;
  model ntumors = Age BMI | FamilyHx LengthofStay IL6 CRP 
    Experience | CancerStage / solution dist=poisson;
  random intercept / subject=HID;
  random intercept / subject=DID(HID);
run;

proc glimmix noclprint chol method=quad(qpoints=7);
  class Sex CancerStage DID;
  model nmorphine = Age Sex LengthofStay BMI CancerStage / solution dist=poisson;
  random intercept BMI / subject=DID;
run;

proc glimmix noclprint chol method=laplace;
  class FamilyHx CancerStage DID HID;
  model remission = Age LengthofStay FamilyHx IL6 CRP CancerStage 
    Experience / solution dist=binomial;
  random intercept / subject=HID;
  random intercept LengthofStay / subject=DID(HID);
run;

proc glimmix noclprint chol method=quad(qpoints=7);
  class SmokingHx FamilyHx School DID;
  model lungcapacity = RBC IL6 | CRP SmokingHx | FamilyHx 
    Experience School / solution dist=beta link=logit;
  random intercept / subject=DID;
run;