DATA LIST LIST/ s trt pre_a pre_b post_a post_b pre_cov post_cov.
BEGIN DATA.
1.00 1.00 3.00 5.00 4.00 7.00 2.00 4.00
2.00 1.00 3.00 7.00 2.00 9.00 3.00 3.00
3.00 1.00 4.00 6.00 7.00 9.00 4.00 8.00
4.00 1.00 2.00 8.00 4.00 8.00 3.00 9.00
5.00 1.00 2.00 4.00 5.00 8.00 2.00 7.00
6.00 2.00 4.00 5.00 8.00 9.00 1.00 2.00
7.00 2.00 4.00 4.00 8.00 1.00 8.00 8.00
8.00 2.00 3.00 7.00 7.00 2.00 5.00 7.00
9.00 2.00 2.00 2.00 4.00 3.00 4.00 3.00
10.00 2.00 5.00 3.00 3.00 8.00 3.00 2.00
END DATA.
* 1. Regular doubly multivariate ANOVA.
* effect of time, trt, time*trt on 2 dependent variables a & b.
* 1a. doubly multivariate anova using GLM, the easy way.
* can assess trt, time, trt*time .
* could assess if effect of trt*time differs by a vs b, see 2a.
GLM pre_a post_a pre_b post_b BY trt
/WSFACTOR = time 2
/MEASURE = a b
/WSDESIGN = time
/DESIGN = trt
/LMATRIX "compare trt 1 vs trt 2" trt 1 -1
/MMATRIX="a vs b by pre vs post" pre_a 1 post_a -1 pre_b -1 post_b 1
/PRINT = TEST(LMATRIX MMATRIX).
* 1b. doubly multivariate anova using MANOVA, the easy way.
* can assess trt, time, trt*time.
* cannot assess differential impact on DVs this way.
MANOVA pre_a post_a pre_b post_b by trt(1,2)
/WSFACTORS time(2)
/ERROR = W.
* 1c. doubly multivariate anova, the hard way, by specifying
* within effects via TRANSFORM.
* get effects of trt, time, trt by time.
MANOVA pre_a post_a pre_b post_b by trt(1,2)
/TRANSFORM(pre_a post_a / pre_b post_b)=SPECIAL(1 1
1 -1)
/PRINT=TRANSFORM
/RENAME= a preposta b prepostb
/ANALYSIS=( a b / prepsta prepostb)
/DESIGN=trt CONSTANT.
* 2. doubly multivariate anova, assessing differential effects on DVs.
* 2a. doubly multivariate anova using GLM, the easy way.
* to assess differential effects, use LMATRIX and MMATRIX.
* if effect of trt and trt*time differs by a vs b.
GLM pre_a post_a pre_b post_b BY trt
/WSFACTOR = time 2
/MEASURE = a b
/WSDESIGN = time
/DESIGN = trt
/LMATRIX="compare trt 1 vs trt 2" trt 1 -1
/MMATRIX "a vs b" pre_a 1 post_a 1 pre_b -1 post_b -1 ;
"a vs b by time" pre_a 1 post_a -1 pre_b -1 post_b 1
/PRINT = TEST(LMATRIX MMATRIX).
* 2b. doubly multivariate anova, the hard way, by .
* specifying within effects via transform.
* to assess differential effects, use TRANSFORM and ANALYSIS.
* to see if effect of trt and trt*time differ by a vs b.
* see effects.
* trt*avsb for trt diff by ab.
* trt*abprepst for trt prepost diff by a vs b.
MANOVA pre_a post_a pre_b post_b by trt(1,2)
/TRANSFORM(pre_a post_a pre_b post_b)=SPECIAL(1 1 1 1
1 1 -1 -1
1 -1 1 -1
1 -1 -1 1)
/PRINT=TRANSFORM
/RENAME= int avsb prevpost abprepst
/ANALYSIS=( avsb / prevpost / abprepst )
/DESIGN=trt CONSTANT.
finish.
* 3a. doubly multivariate, as a univariate.
GLM pre_a post_a pre_b post_b by trt
/WSFACTORS ab 2 time 2.
* 3b. doubly multivariate, as a univariate.
MANOVA pre_a post_a pre_b post_b by trt(1,2)
/WSFACTORS ab(2) time(2).
* 4a. effect of b, adjusting for variable a.
* actually, all dvs are adjusted by all covariates.
GLM pre_b post_b by trt with pre_a post_a
/WSFACTORS time 2
/PRINT=PARAMETER.
* 4b. univariate with covariates.
MANOVA pre_b post_b by trt(1,2) with pre_a post_a
/WSFACTORS time(2)
/PRINT=PARAMETERS(estim).
*5 univariate with covariates.
* convert to long format, and analyze using manova and glm.
*6 same as number 5, but test for changes in covariates.