You can read the Hospital Doctor Patient Dataset into SPSS and run many linear and generalized linear mixed effects models in SPSS using this code. The output is not included, but the syntax is. For more details on the dataset, you should see the original R page that simulates the data HDP Simulation. You can download the dataset as a comma separated value (CSV) hdp.csv.
GET DATA
/TYPE=TXT
/FILE="C:UsersjwileyDesktophdp.csv"
/DELCASE=LINE
/DELIMITERS=","
/ARRANGEMENT=DELIMITED
/FIRSTCASE=2
/IMPORTCASE=ALL
/VARIABLES=
tumorsize F co2 F pain F wound F mobility F
ntumors F nmorphine F remission F lungcapacity F Age F
Married F FamilyHx A3 SmokingHx A7 Sex A6 CancerStage A3
LengthofStay F WBC F RBC F BMI F IL6 F CRP F DID F Experience F
School A7 Lawsuits F HID F Medicaid F.
CACHE.
EXECUTE.
DATASET NAME HDP WINDOW=FRONT.
VARIABLE LEVEL tumorsize co2 pain wound mobility ntumors nmorphine lungcapacity (scale)
/Age LengthofStay WBC RBC BMI IL6 CRP Experience Lawsuits Medicaid (scale)
/remission Married FamilyHx SmokingHx Sex CancerStage School DID HID (nominal).
VARIABLE ROLE
/TARGET tumorsize co2 pain wound mobility ntumors nmorphine lungcapacity
/INPUT Age LengthofStay WBC RBC BMI IL6 CRP Experience Lawsuits Medicaid
/INPUT Married FamilyHx SmokingHx Sex CancerStage School
/NONE DID HID.
MIXED tumorsize BY FamilyHx CancerStage SmokingHx WITH Age LengthofStay
/FIXED=FamilyHx CancerStage Age LengthofStay SmokingHx SmokingHx*Age
/METHOD=REML
/PRINT=G SOLUTION
/RANDOM=INTERCEPT LengthofStay | SUBJECT(DID) COVTYPE(VC).
MIXED co2 BY FamilyHx CancerStage SmokingHx WITH Age LengthofStay
/FIXED=FamilyHx CancerStage Age LengthofStay SmokingHx SmokingHx*Age
/METHOD=REML
/PRINT=G SOLUTION
/RANDOM=INTERCEPT LengthofStay | SUBJECT(DID) COVTYPE(VC).
MIXED pain BY Sex WITH IL6 CRP
/FIXED=Sex IL6 CRP IL6*CRP
/METHOD=REML
/PRINT=G SOLUTION
/RANDOM=INTERCEPT | SUBJECT(DID) COVTYPE(VC).
MIXED wound BY Sex Married WITH RBC Experience
/FIXED=RBC Sex Married Sex*Married Experience
/METHOD=REML
/PRINT=G SOLUTION
/RANDOM=INTERCEPT | SUBJECT(HID) COVTYPE(VC)
/RANDOM=INTERCEPT RBC | SUBJECT(HID*DID) COVTYPE(VC).
MIXED mobility BY School WITH Age BMI Experience Lawsuits Medicaid
/FIXED=School Age BMI Experience Lawsuits Medicaid
/METHOD=REML
/PRINT=G SOLUTION
/RANDOM=INTERCEPT | SUBJECT(HID) COVTYPE(VC)
/RANDOM=INTERCEPT | SUBJECT(HID*DID) COVTYPE(VC).
GENLINMIXED
/DATA_STRUCTURE SUBJECTS=HID*DID
/FIELDS TARGET=ntumors TRIALS=NONE OFFSET=NONE
/TARGET_OPTIONS DISTRIBUTION=POISSON LINK=LOG
/FIXED EFFECTS=Age BMI FamilyHx LengthofStay CancerStage IL6 CRP Experience FamilyHx*BMI
CancerStage*Experience USE_INTERCEPT=TRUE
/RANDOM USE_INTERCEPT=TRUE SUBJECTS=HID COVARIANCE_TYPE=VARIANCE_COMPONENTS
/RANDOM USE_INTERCEPT=TRUE SUBJECTS=HID*DID COVARIANCE_TYPE=VARIANCE_COMPONENTS
/BUILD_OPTIONS INPUTS_CATEGORY_ORDER=DESCENDING MAX_ITERATIONS=100.
GENLINMIXED
/DATA_STRUCTURE SUBJECTS=DID
/FIELDS TARGET=nmorphine TRIALS=NONE OFFSET=NONE
/TARGET_OPTIONS DISTRIBUTION=POISSON LINK=LOG
/FIXED EFFECTS=Age Sex LengthofStay BMI CancerStage USE_INTERCEPT=TRUE
/RANDOM EFFECTS=BMI USE_INTERCEPT=TRUE SUBJECTS=DID COVARIANCE_TYPE=VARIANCE_COMPONENTS
/BUILD_OPTIONS INPUTS_CATEGORY_ORDER=DESCENDING MAX_ITERATIONS=100.
GENLINMIXED
/DATA_STRUCTURE SUBJECTS=HID*DID
/FIELDS TARGET=remission TRIALS=NONE OFFSET=NONE
/TARGET_OPTIONS DISTRIBUTION=BINOMIAL LINK=LOGIT
/FIXED EFFECTS=Age LengthofStay FamilyHx IL6 CRP BMI CancerStage Experience USE_INTERCEPT=TRUE
/RANDOM USE_INTERCEPT=TRUE SUBJECTS=HID COVARIANCE_TYPE=VARIANCE_COMPONENTS
/RANDOM EFFECTS=LengthofStay USE_INTERCEPT=TRUE SUBJECTS=DID*HID COVARIANCE_TYPE=VARIANCE_COMPONENTS
/BUILD_OPTIONS INPUTS_CATEGORY_ORDER=DESCENDING MAX_ITERATIONS=100.
GENLINMIXED
/DATA_STRUCTURE SUBJECTS=DID
/FIELDS TARGET=lungcapacity TRIALS=NONE OFFSET=NONE
/TARGET_OPTIONS DISTRIBUTION=NORMAL LINK=LOG
/FIXED EFFECTS=RBC IL6 CRP IL6*CRP SmokingHx FamilyHx SmokingHx*FamilyHx
Experience School USE_INTERCEPT=TRUE
/RANDOM USE_INTERCEPT=TRUE SUBJECTS=DID COVARIANCE_TYPE=VARIANCE_COMPONENTS
/BUILD_OPTIONS INPUTS_CATEGORY_ORDER=DESCENDING MAX_ITERATIONS=100.